<![CDATA[
<%@ Language=VBScript %>
<%
'Con-way XML Sample Code for ASP - Service Center Details interface
'-----------------
'TODO: replace the USERNAME and PASSWORD String values below
'with your Con-way username and password
'-----------------
'Send questions to Con-way XML Support at xmlsupport@Con-way.com
Option Explicit
' Declare Variables
Dim title '
Dim requestType 'The XML Request type
Dim conwayXmlUrl 'The secure POST URL for the XML Request
Dim xmlRequest 'a string to hold XML Request document
Dim xmlResponse 'an XML DOM object to hold the XML Response document
Dim myElement1 'first element to retrieve from XML Response
Dim myElement2 'second element to retrieve from XML Response
Dim myElementList1 'NodeList for my first element
Dim myElementList2 'NodeList for my second element
Dim httpConn 'an object for the HTTP connection to www.Con-way.com
Dim username 'for authentication to Con-way secure site
Dim password 'for authentication to Con-way secure site
Dim myInputArgs() 'array to hold your input arguments
title = "Service Center Details"
requestType = "ServiceCenterDetailsRequest"
conwayXmlUrl = "https://www.Con-way.com/webapp/servicecenter_app/ServiceCenterDetailsServlet"
myElement1 = "SIC"
myElement2 = "Name"
' replace the "USERNAME" & "PASSWORD" String values with your Con-way username and password
username = "USERNAME"
password = "PASSWORD"
' *** Also add a valid CustRefNbr value in that element below
' Build XML Request - For this sample we will just hard code some dummy data.
Redim myInputArgs(1) 'set index to number of items (only one for Service Center Details
myInputArgs(0) = "19348"
xmlRequest="<ServiceCenterDetailsRequest testmode=""Y"">"
Dim i
For i=0 to UBound(myInputArgs)-1
xmlRequest = xmlRequest & "<PostalCode country=""US"">" & myInputArgs(i) & "</PostalCode>"
Next
xmlRequest = xmlRequest & "</ServiceCenterDetailsRequest>"
' Convert characters to proper format for HTTP POST
xmlRequest = Server.URLEncode(xmlRequest)
'*Call Con-way XML Interface.
' The XMLHTTP classes used here are availible from Microsoft and
' are autmatically installed and registered with Internet Explorer.
' For more info on how to use these classes please see http://msdn.microsoft.com/xml/
set httpConn = Server.CreateObject("Microsoft.XMLHTTP")
'or alternately depending on what is installed on your server:
'set httpConn = Server.CreateObject("MSXML2.ServerXMLHTTP")
'or whatever parser you have installed
' open synchronous connection to X-ShipmentStatus
httpConn.open "POST",conwayXmlUrl,false,username,password
'set post data type, and post data
httpConn.setRequestHeader "Content-type","application/x-www-form-urlencoded"
httpConn.Send requestType & "=" & xmlRequest
'*Parse the response
' This example uses the MS XML DOM classes that ship with IE 5.5 or the XML SDK
' to create an XML document. Here we simple redisplay the XML data, but in a real
' world scenario you will parse the document to locate the data you wish to display
' or save, such as the net charge, transit time, and disclaimer.
'*For more info on how to use the MS XML SDK please see
' http://msdn.microsoft.com/xml/index.asp
' If you need only the final net charge of the quote you might find it easier
' in some cases to use a simpler method such as 'InStr'.
set xmlResponse = Server.CreateObject("Microsoft.XMLDOM") 'create XML DOM object
'or alternately, based on what is installed on your server:
'set shpResponse = Server.CreateObject("MSXML2.DOMDocument")
set xmlResponse = httpConn.responseXML
%>
<html>
<head>
<title>Sample ASP for Con-way XML <%=title%></title>
</head>
<body text="Darkorange">
<center>
<B><FONT face="Arial" size=+1><I>Sample ASP Con-way XML <%=title%></I></FONT></B>
</center>
<br>
<b>This is the complete XML Response output for <%=title%>:</b>
<br><br>
<code><%=xmlResponse.xml%></code>
<br><br>
<b>This is the data for the elements (<%=myElement1%>, <%=myElement2%>) retrieved from the XML Response:</b>
<br>
<%
'Here is how to a value out of a specific XML element using MS XML:
'Get node lists of elements in the response with a given name
set myElementList1 = xmlResponse.getElementsByTagName(myElement1)
set myElementList2 = xmlResponse.getElementsByTagName(myElement2)
'Process the Nodelists as desired
For i = 0 To (myElementList1.length - 1)
response.write("<br><b>" & myElement1 & " = " & myElementList1.Item(i).Text &_
"<br>" & myElement2 & " = " & myElementList2.Item(i).Text & "</b>")
Next
%>
</body>
</html>
]]>